[Nagiosplug-checkins] nagiosplug/m4 basename.m4, NONE, 1.1 dos.m4, NONE, 1.1 np_coreutils.m4, 1.7, 1.8

[Ton Voon]

Update of /cvsroot/nagiosplug/nagiosplug/m4
In directory sc8-pr-cvs7.sourceforge.net:/tmp/cvs-serv3873/m4

Modified Files:
	np_coreutils.m4 
Added Files:
	basename.m4 dos.m4 
Log Message:
Using coreutils' base_name function because of portability issues with
Tru64


--- NEW FILE: basename.m4 ---
# basename.m4 serial 1
dnl Copyright (C) 2005 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_BASENAME],
[
  AC_LIBSOURCES([basename.c, dirname.h])
  AC_LIBOBJ([basename])

  dnl Prerequisites of lib/basename.c.
  AC_REQUIRE([gl_AC_DOS])
])

--- NEW FILE: dos.m4 ---
#serial 9

# Define some macros required for proper operation of code in lib/*.c
# on MSDOS/Windows systems.

# Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# From Jim Meyering.

AC_DEFUN([gl_AC_DOS],
  [
    AC_CACHE_CHECK([whether system is Windows or MSDOS], [ac_cv_win_or_dos],
      [
        AC_TRY_COMPILE([],
        [#if !defined _WIN32 && !defined __WIN32__ && !defined __MSDOS__ && !defined __CYGWIN__
neither MSDOS nor Windows
#endif],
        [ac_cv_win_or_dos=yes],
        [ac_cv_win_or_dos=no])
      ])

    if test x"$ac_cv_win_or_dos" = xyes; then
      ac_fs_accepts_drive_letter_prefix=1
      ac_fs_backslash_is_file_name_separator=1
    else
      ac_fs_accepts_drive_letter_prefix=0
      ac_fs_backslash_is_file_name_separator=0
    fi

    AH_VERBATIM(FILE_SYSTEM_PREFIX_LEN,
    [#if FILE_SYSTEM_ACCEPTS_DRIVE_LETTER_PREFIX
# define FILE_SYSTEM_PREFIX_LEN(Filename) \
  ((Filename)[0] && (Filename)[1] == ':' ? 2 : 0)
#else
# define FILE_SYSTEM_PREFIX_LEN(Filename) 0
#endif])

    AC_DEFINE_UNQUOTED([FILE_SYSTEM_ACCEPTS_DRIVE_LETTER_PREFIX],
      $ac_fs_accepts_drive_letter_prefix,
      [Define on systems for which file names may have a so-called
       `drive letter' prefix, define this to compute the length of that
       prefix, including the colon.])

    AH_VERBATIM(ISSLASH,
    [#if FILE_SYSTEM_BACKSLASH_IS_FILE_NAME_SEPARATOR
# define ISSLASH(C) ((C) == '/' || (C) == '\\')
#else
# define ISSLASH(C) ((C) == '/')
#endif])

    AC_DEFINE_UNQUOTED([FILE_SYSTEM_BACKSLASH_IS_FILE_NAME_SEPARATOR],
      $ac_fs_backslash_is_file_name_separator,
      [Define if the backslash character may also serve as a file name
       component separator.])
  ])

Index: np_coreutils.m4
===================================================================
RCS file: /cvsroot/nagiosplug/nagiosplug/m4/np_coreutils.m4,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -d -r1.7 -r1.8
--- np_coreutils.m4	11 Jul 2006 12:38:08 -0000	1.7
+++ np_coreutils.m4	13 Jul 2006 08:54:57 -0000	1.8
@@ -11,6 +11,7 @@
 AC_DEFUN([np_COREUTILS],
 [
   AC_REQUIRE([AM_STDBOOL_H])
+  AC_REQUIRE([gl_BASENAME])
   AC_REQUIRE([gl_C_STRTOLD])
   AC_REQUIRE([gl_EXITFAIL])
   AC_REQUIRE([gl_FCNTL_SAFER])