3 files changed, 73 insertions, 0 deletions

diff --git a/m4/basename.m4 b/m4/basename.m4
new file mode 100644
index 00000000..69a0996f
--- /dev/null
+++ b/m4/basename.m4
@@ -0,0 +1,14 @@
+# basename.m4 serial 1
+dnl Copyright (C) 2005 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([gl_BASENAME],
+[
+  AC_LIBSOURCES([basename.c, dirname.h])
+  AC_LIBOBJ([basename])
+
+  dnl Prerequisites of lib/basename.c.
+  AC_REQUIRE([gl_AC_DOS])
+])
diff --git a/m4/dos.m4 b/m4/dos.m4
new file mode 100644
index 00000000..0713cf14
--- /dev/null
+++ b/m4/dos.m4
@@ -0,0 +1,58 @@
+#serial 9
+
+# Define some macros required for proper operation of code in lib/*.c
+# on MSDOS/Windows systems.
+
+# Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# From Jim Meyering.
+
+AC_DEFUN([gl_AC_DOS],
+  [
+    AC_CACHE_CHECK([whether system is Windows or MSDOS], [ac_cv_win_or_dos],
+      [
+        AC_TRY_COMPILE([],
+        [#if !defined _WIN32 && !defined __WIN32__ && !defined __MSDOS__ && !defined __CYGWIN__
+neither MSDOS nor Windows
+#endif],
+        [ac_cv_win_or_dos=yes],
+        [ac_cv_win_or_dos=no])
+      ])
+
+    if test x"$ac_cv_win_or_dos" = xyes; then
+      ac_fs_accepts_drive_letter_prefix=1
+      ac_fs_backslash_is_file_name_separator=1
+    else
+      ac_fs_accepts_drive_letter_prefix=0
+      ac_fs_backslash_is_file_name_separator=0
+    fi
+
+    AH_VERBATIM(FILE_SYSTEM_PREFIX_LEN,
+    [#if FILE_SYSTEM_ACCEPTS_DRIVE_LETTER_PREFIX
+# define FILE_SYSTEM_PREFIX_LEN(Filename) \
+  ((Filename)[0] && (Filename)[1] == ':' ? 2 : 0)
+#else
+# define FILE_SYSTEM_PREFIX_LEN(Filename) 0
+#endif])
+
+    AC_DEFINE_UNQUOTED([FILE_SYSTEM_ACCEPTS_DRIVE_LETTER_PREFIX],
+      $ac_fs_accepts_drive_letter_prefix,
+      [Define on systems for which file names may have a so-called
+       `drive letter' prefix, define this to compute the length of that
+       prefix, including the colon.])
+
+    AH_VERBATIM(ISSLASH,
+    [#if FILE_SYSTEM_BACKSLASH_IS_FILE_NAME_SEPARATOR
+# define ISSLASH(C) ((C) == '/' || (C) == '\\')
+#else
+# define ISSLASH(C) ((C) == '/')
+#endif])
+
+    AC_DEFINE_UNQUOTED([FILE_SYSTEM_BACKSLASH_IS_FILE_NAME_SEPARATOR],
+      $ac_fs_backslash_is_file_name_separator,
+      [Define if the backslash character may also serve as a file name
+       component separator.])
+  ])
diff --git a/m4/np_coreutils.m4 b/m4/np_coreutils.m4
index 5360bbd0..77cb9f69 100644
--- a/m4/np_coreutils.m4
+++ b/m4/np_coreutils.m4
@@ -11,6 +11,7 @@ dnl Usually in coreutils' prereq.m4, but this is a subset that we need
 AC_DEFUN([np_COREUTILS],
 [
   AC_REQUIRE([AM_STDBOOL_H])
+  AC_REQUIRE([gl_BASENAME])
   AC_REQUIRE([gl_C_STRTOLD])
   AC_REQUIRE([gl_EXITFAIL])
   AC_REQUIRE([gl_FCNTL_SAFER])